Remove "2" from Qt Quick Controls directories

Qt Quick Controls 2 was named that way because it was a follow-up to
Qt Quick Controls 1.x. Now that Qt Quick Controls 1 is no longer
supported, we don't need to have "2" in the name. Work on this was
already started for the documentation in
1abdfe5d5a052f2298b7bf657513dfa7e0c66a56.

By doing this renaming a few weeks before feature freeze, it won't
affect the release but still results in as little time possible spent
manually fixing conflicts in cherry-picks from non-LTS releases as a
result of the renaming.

This patch does the following:

- Renames directories.
- Adapts CMakeLists.txt and other files to account for the new paths.

A follow-up patch will handle documentation.

It does not touch library names or other user-facing stuff, as that
will have to be done in Qt 7.

Task-number: QTBUG-95413
Change-Id: I170d8db19033ee71e495ff0c5c1a517a41ed7634
Reviewed-by: Mitch Curtis <mitch.curtis@qt.io>

1 files changed, 61 insertions, 0 deletions

diff --git a/src/quickcontrols/ios/Drawer.qml b/src/quickcontrols/ios/Drawer.qml
new file mode 100644
index 0000000000..52cdb8b372
--- /dev/null
+++ b/src/quickcontrols/ios/Drawer.qml
@@ -0,0 +1,61 @@
+// Copyright (C) 2022 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
+
+import QtQuick
+import QtQuick.Templates as T
+import QtQuick.Controls.impl
+import QtQuick.Controls.iOS.impl
+
+T.Drawer {
+    id: control
+
+    parent: T.Overlay.overlay
+
+    implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
+                            contentWidth + leftPadding + rightPadding)
+    implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
+                             contentHeight + topPadding + bottomPadding)
+
+    property real inset: control.dim ? 8 : 0
+    property bool vertical: control.edge === Qt.LeftEdge || control.edge === Qt.RightEdge
+
+    rightInset: background && control.edge === Qt.LeftEdge ? -inset : 0
+    leftInset: background && control.edge === Qt.RightEdge ? -inset : 0
+    bottomInset: background && control.edge === Qt.TopEdge ? -inset : 0
+    topInset: background && control.edge === Qt.BottomEdge ? -inset : 0
+
+    enter: Transition { SmoothedAnimation { velocity: 5 } }
+    exit: Transition { SmoothedAnimation { velocity: 5 } }
+
+    background: Item {
+        NinePatchImage {
+            source: IOS.url + "drawer-background"
+            NinePatchImageSelector on source {
+                states: [
+                    {"light": Qt.styleHints.appearance === Qt.Light},
+                    {"dark": Qt.styleHints.appearance === Qt.Dark},
+                    {"modal": control.modal}
+                ]
+            }
+            y: (parent.height - height) / 2
+            x: (parent.width - width) / 2
+            rotation: control.edge === Qt.TopEdge ? 90 : (control.edge === Qt.BottomEdge ? -90
+                                                  : (control.edge === Qt.RightEdge ? 180 : 0))
+            width: vertical ? parent.width : parent.height
+            height: vertical ? parent.height : parent.width
+        }
+        Rectangle {
+            width: vertical ? 1 : parent.width
+            height: vertical ? parent.height : 1
+            color: control.palette.mid
+            x: control.edge === Qt.LeftEdge ? parent.width - 1 - inset : (control.edge === Qt.RightEdge ? inset : 0)
+            y: control.edge === Qt.BottomEdge ? inset : (control.edge === Qt.TopEdge ? parent.height - 1 - inset : 0)
+            z: 10
+        }
+    }
+
+    T.Overlay.modal: Rectangle {
+        color: Color.transparent(control.palette.mid, 0.5)
+        Behavior on opacity { NumberAnimation { duration: 150 } }
+    }
+}