feat: migrated to Nushell's own url functionality

Author: vyadh

nut/package.nu

@@ -0,0 +1,31 @@
+
+# Resolve package information to a canonical form.
+export def resolve [
+    type: string, version: string
+]: string -> record<scheme:string, host:string, path:string, fragment:string, type:string, version:string,> {
+    let url = $in | url parse | validate
+
+    $url
+        | select scheme host path fragment
+        | update host { |it| $it.host | str downcase }
+        | update path { |it| $it.path | str replace --regex '\.git$' '' }
+        | insert type $type
+        | insert version $version
+}
+
+def validate []: record -> record {
+    let url = $in
+    if ($url.scheme not-in ["https", "file"]) {
+        error make { msg: $"Unsupported scheme: ($url.scheme)" }
+    }
+    if ($url.path == "/") {
+        error make { msg: $"Empty path is unsupported" }
+    }
+    if ($url.username != "" or $url.password != "") {
+        error make { msg: $"Credentials are unsupported" }
+    }
+    if ($url.port != "") {
+        error make { msg: $"Port is unsupported" }
+    }
+    $url
+}

nut/package_id.nu

@@ -0,0 +1,78 @@
+use ../nut/package.nu
+use std assert
+
+# [test]
+def "resolve id with normal data" [] {
+    let result = "https://example.com/path/repo" | package resolve "module" "v0.1.0"
+
+    assert equal $result {
+        scheme: "https"
+        host: "example.com"
+        path: "/path/repo"
+        fragment: ""
+        type: "module"
+        version: "v0.1.0"
+    }
+}
+
+# [test]
+def "resolve id always results in lower case domain only" [] {
+    let result = "https://NuCo.com/path/MyRepo" | package resolve "" ""
+
+    assert equal ($result | select host path) {
+        host: "nuco.com"
+        path: "/path/MyRepo"
+    }
+}
+
+# [test]
+def "resolve id removes git postfix" [] {
+    let result = "https://example.com/path/repo.git" | package resolve "" ""
+
+    assert equal ($result | select path) {
+        path: "/path/repo"
+    }
+}
+
+# [test]
+def "resolve validates scheme" [] {
+    assert equal ("https://example.com/repo" | package resolve "" "" | get scheme) "https"
+    assert equal ("file://example.com/repo" | package resolve "" "" | get scheme) "file"
+    assert equal (catch-error { "http://example.com/repo" | package resolve "" "" }) "Unsupported scheme: http"
+}
+
+# [test]
+def "resolve validates when unsupported urls" [] {
+    assert equal (catch-error { "https://example.com" | package resolve "" "" }) "Empty path is unsupported"
+    assert equal (catch-error { "https://user:[email protected]/repo" | package resolve "" "" }) "Credentials are unsupported"
+    assert equal (catch-error { "https://example.com:123/repo" | package resolve "" "" }) "Port is unsupported"
+
+    # todo Might want to validate this
+    assert equal ("https://invalid_domain/repo" | package resolve "" "" | get host) "invalid_domain"
+}
+
+# [test]
+def "parse with fragment" [] {
+    let result = "https://github.com/vyadh/nut#semver" | package resolve "" "" | get fragment
+
+    assert equal $result "semver"
+}
+
+def catch-error [job: closure]: nothing -> string {
+    try {
+        do $job
+        error make { msg: "no-error" }
+    } catch { |error|
+        if ($error.msg == "no-error") {
+            error make {
+                msg: "Expected an error"
+                label: {
+                    text: "from here"
+                    span: (metadata $job).span
+                }
+            }
+        } else {
+            $error.msg
+        }
+    }
+}