破解虫食算之谜-CSDN博客

题目描述

 所谓虫食算，就是原先的算式中有一部分被虫子啃掉了，需要我们根据剩下的数字来判定被啃掉的字母。来看一个简单的例子：

43#9865#045

　+　　8468#6633

　　= 44445509678

其中#号代表被虫子啃掉的数字。根据算式，我们很容易判断：第一行的两个数字分别是5和3，第二行的数字是5。

现在，我们对问题做两个限制：

首先，我们只考虑加法的虫食算。这里的加法是N进制加法，算式中三个数都有N位，允许有前导的0。

其次，虫子把所有的数都啃光了，我们只知道哪些数字是相同的，我们将相同的数字用相同的字母表示，不同的数字用不同的字母表示。如果这个算式是N进制的，我们就取英文字母表午的前N个大写字母来表示这个算式中的0到N-1这N个不同的数字：但是这N个字母并不一定顺序地代表0到N-1)。输入数据保证N个字母分别至少出现一次。

BADC

+ CBDA

= DCCC

上面的算式是一个4进制的算式。很显然，我们只要让ABCD分别代表0123，便可以让这个式子成立了。你的任务是，对于给定的N进制加法算式，求出N个不同的字母分别代表的数字，使得该加法算式成立。输入数据保证有且仅有一组解

输入

输入文件alpha.in包含4行。第一行有一个正整数N(N<=26)，后面的3行每行有一个由大写字母组成的字符串，分别代表两个加数以及和。这3个字符串左右两端都没有空格，从高位到低位，并且恰好有N位。

输出

输出文件alpha.out包含一行。在这一行中，应当包含唯一的那组解。解是这样表示的：输出N个数字，分别表示A，B，C……所代表的数字，相邻的两个数字用一个空格隔开，不能有多余的空格。

样例输入

ABCED

BDACE

EBBAA

样例输出

1 0 3 4 2

数据范围限制

【数据规模】

对于30％的数据，保证有N<＝10；

对于50％的数据，保证有N<＝15；

对于全部的数据，保证有N<＝26。

程序

var
        a:array['A'..'Z']of integer;
        b:array[1..26,1..3]of char;
        h:array['A'..'Z']of boolean;
        n,i,j,l:integer;ch:char;
        v:array[0..26]of boolean;
        c:array[1..26]of char;
function pan:boolean;
var
        i,j,k:integer;
begin
        k:=0;
        for i:=n downto 2 do
        begin
                k:=k+a[b[i,1]]+a[b[i,2]];
                if k mod n<>a[b[i,3]] then exit(false);
                k:=k div n;
        end;
        k:=k+a[b[1,1]]+a[b[1,2]];
        if k<>a[b[1,3]] then exit(false);
        exit(true);
end;
function pan2:boolean;
var
        i:integer;
begin
        for i:=n downto 1 do
        if (a[b[i,1]]<>-1)and(a[b[i,2]]<>-1)and(a[b[i,3]]<>-1)and
        ((a[b[i,1]]+a[b[i,2]])mod n<>a[b[i,3]])and((a[b[i,1]]+a[b[i,2]]+1)mod n<>a[b[i,3]]) then exit(true);
        exit(false);
end;
procedure shuchu;
var
        i:integer;
begin
        for i:=1 to n-1 do
        write(a[chr(i+64)],' ');
        writeln(a[chr(n+64)]);
        halt;
end;
procedure sosuo(j:integer);
var
        cc:char;
        i:integer;
begin
        if pan2 then exit;
        if a[b[1,1]]+a[b[1,2]]>=n then exit;
        if j>n then
        begin
                if pan then
                shuchu;
                exit;
        end;
        for i:=n-1 downto 0 do
        if v[i] then
        begin
                a[c[j]]:=i;
                v[i]:=false;
                sosuo(j+1);
                a[c[j]]:=-1;
                v[i]:=true;
        end;
end;
begin
        assign(input,'alpha.in');reset(input);
        assign(output,'alpha.out');rewrite(output);
        readln(n);
        fillchar(v,sizeof(v),true);
        for i:=1 to n do a[chr(i+64)]:=-1;
        fillchar(h,sizeof(h),true);
        for j:=1 to 3 do
        begin
                for i:=1 to n do  read(b[i,j]);
                readln;
        end;
        for i:=n downto 1 do for j:=1 to 3 do
        if h[b[i,j]] then
        begin
                inc(l);
                c[l]:=b[i,j];
                h[b[i,j]]:=false;
        end;
        sosuo(1);
        close(input);
        close(output);
end.