使用多边形裁减影像

最新推荐文章于 2024-08-01 17:37:09 发布

转载最新推荐文章于 2024-08-01 17:37:09 发布 · 146 阅读

CC 4.0 BY-SA版权

原文链接：http://www.cnblogs.com/njlhb/archive/2008/04/18/1160378.html

本文介绍了一种在ArcGIS中使用Python脚本裁剪栅格数据的方法。通过判断输入数据类型，无论是栅格图层、栅格数据集还是直接的栅格，都能进行裁剪操作。文章详细解释了如何设置裁剪区域、分析环境和输出结果，确保裁剪后的栅格与指定的多边形范围一致。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

Public Function ClipRasterByPolgon(pInGeoDataset As IGeoDataset, pPolygon As IPolygon) As IRaster
Dim pRaster As IRaster
If TypeOf pInGeoDataset Is IRasterLayer Then
      Dim pRasterlayer As IRasterLayer
      Set pRasterlayer = pInGeoDataset
      Set pRaster = pRasterlayer.Raster
ElseIf TypeOf pInGeoDataset Is IRasterDataset Then
      Dim pRasterDataset As IRasterDataset
      Set pRasterDataset = pInGeoDataset
      Set pRaster = pRasterDataset.CreateDefaultRaster
ElseIf TypeOf pInGeoDataset Is IRaster Then
      Set pRaster = pInGeoDataset
Else
      Exit Function
End If

Dim pInputDataset As IGeoDataset
Set pInputDataset = pRaster

Dim pExtractionOp As IExtractionOp
Set pExtractionOp = New RasterExtractionOp
Dim pRasterAnalysisEnvironment As IRasterAnalysisEnvironment
Set pRasterAnalysisEnvironment = pExtractionOp
pRasterAnalysisEnvironment.SetCellSize esriRasterEnvValue, GetRasterCellSize(pRaster)
pRasterAnalysisEnvironment.SetExtent esriRasterEnvValue, pPolygon.Envelope

Dim pOutputDataset As IGeoDataset
Set pOutputDataset = pExtractionOp.Polygon(pInputDataset, pPolygon, True)

Set ClipRasterByPolgon = pOutputDataset
End Function

Public Function GetRasterCellSize(pRaster As IRaster) As Double
Dim pProps As IRasterProps
Set pProps = pRaster
GetRasterCellSize = pProps.MeanCellSize.X
End Function

注意：pPolygon 的ISpatialReference要与RASTER的一样如果不一样，可以使用
pGeometry.Project pRasterSpatialReference来设定

转载于:https://www.cnblogs.com/njlhb/archive/2008/04/18/1160378.html