win配置exe开机自启

Win配置开机自启

法1：启动文件夹

1. Win+R键调出运行窗口，输入shell:startup命令
2. 把exe快捷方式放到该启动文件夹

法2：注册表添加开机自启动程序

1. Win+R键调出运行窗口，输入regedit命令
2. 打开路径：计算机\HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run
3. 在右边空白处右键新建，选择字符串值(S)，生成的新值并命名一个名称
4. 在数值数据中添加需要开机自启的软件路径，点击确认即可；

法3：bat脚本+任务计划

以开机启动SSMS为例

编写bat脚本

编写startSSMS.bat,想启动其他程序修改应用配置部分即可。

:: 关闭命令回显
@echo off
:: 设置命令行为UTF-8编码，以支持中文
chcp 65001
:: 开始本地化环境变量设置
setlocal

:: 应用配置
set APP_NAME=Ssms.exe
set APP_PATH=C:\Program Files (x86)\Microsoft SQL Server Management Studio 20\Common7\IDE\

:: 日志配置
for /f "tokens=2 delims==" %%I in ('wmic os get localdatetime /value') do set datetime=%%I
set YEAR=%datetime:~0,4%
set MONTH=%datetime:~4,2%
set DAY=%datetime:~6,2%
set LOG_DATE=%YEAR%-%MONTH%-%DAY%
set LOG_PREFIX=log_
set LOG_FILE=%LOG_PREFIX%%LOG_DATE%.log

:: 使用tasklist命令检查应用程序是否已经启动
tasklist /FI "IMAGENAME eq %APP_NAME%" 2>NUL | find /I /N "%APP_NAME%">NUL
if "%ERRORLEVEL%"=="0" (
    echo %APP_NAME% 已经在运行。 at %date% %time% >> %LOG_FILE%
) else (
    echo %APP_NAME% 正在启动... at %date% %time% >> %LOG_FILE%
    start "" "%APP_PATH%%APP_NAME%"
    echo %APP_NAME% 启动完成。 at %date% %time% >> %LOG_FILE%
)

endlocal

运行startSSMS.bat，可以启动SSMS，同时产生日志。以管理员运行bat脚本，应用则以管理员身份启动。

创建任务计划

使用Windows任务计划程序来定时执行这个批处理文件。

打开“任务计划程序”。通过按下Win + R键，输入 taskschd.msc 并回车。

点击创建任务

常规选项卡：名称随意，勾选框内三个选项

触发器选项卡：新建-登录时-确认

操作选项卡：新建-启动程序-选择脚本路径-确认

条件选项卡：取消勾选电源下这两个选项

重启测试脚本是否生效