西门子PLC结构化编程_带前馈控制功能的增量式PID控制器

增量式PID与前馈控制实现
原创 于 2025-09-10 14:25:14 发布 · 418 阅读 · 6 ·
CC 4.0 BY-SA版权
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
文章标签：

#西门子PLC #SCL #增量式PID #前馈控制 #PID

文章目录

前言

在文章《西门子PLC结构化编程_带前馈控制功能的位置式PID控制器》中，我们讨论了带前馈控制功能的位置式PID实现方法，现在我们将该算法应用到增量式PID中。

一、功能概述

PID控制功能块应具备以下功能：

  1. 完整的PID实现：包含比例、积分、微分三项计算；
  2. 防积分饱和：可配置的积分上下限，防止积分项过大；
  3. 死区控制：防止控制元件频繁抖动；
  4. 基于过程值的微分：避免设定值变化导致误差过大，造成输出冲击；
  5. 手动/自动无扰切换：在手动模式下保持积分项，切换时无冲击，同时，将当前PID输出值赋给手动设定值；
  6. 输出限幅：可配置的输出上下限，保护执行机构；
  7. 状态监控：提供各项输出用于监控和调试；
  8. 手动模式：PID控制器取消激活，PID输出值等于手动设定值；
  9. 半自动模式：PID控制器激活，设定值SP由操作员手动设置；
  10. 自动模式：PID控制器激活，设定值SP由其它连锁条件计算得出
  11. Kp：增大使响应加快，但过大会导致振荡；
  12. Ti：减小使积分作用增强，消除稳态误差；
  13. Td：增大改善稳定性，抑制超调；
  14. 可选择控制器正作用/反作用；
  15. 如果过程是正作用（控制量增加→过程值增加），则控制器应设置为反作用；
  16. 如果过程是反作用（控制量增加→过程值减少），则控制器应设置为正作用；
  17. 具有前馈控制功能；
  18. 位置式PID当前输出 = 位置式PID上一扫描周期输出 + 增量式PID当前输出。

二、公式推导

在文章《西门子PLC结构化编程_带前馈控制功能的位置式PID控制器》中，我们已经推导出了位置式PID公式以及前馈控制计算公式，这里不再赘述。只给出增量式PID计算公式。
增量式PID算法的核心公式为：
Δu(k) = Kp × [e(k) - e(k-1)] + Ki × e(k) + Kd × [e(k) - 2e(k-1) + e(k-2)]
其中：
Δu(k) = 输出变化量（增量）
e(k) = 当前误差
e(k-1) = 上一次误差
e(k-2) = 上两次误差
Ki = Kp × Δt / Ti（积分系数）
Kd = Kp × Td / Δt（微分系数）

三、程序编写

1. 新建自定义数据类型“1_PID_Controller”

在这里插入图片描述
在这里插入图片描述
图1

2. 新建FB块“FB37_IncPID_Controller_Advanced”

在引脚中添加如下变量：
在这里插入图片描述
图2

3. 编写程序

在这里插入图片描述

REGION 手动、半自动、自动无扰切换
    
    IF #PID.HMI.HMIManual THEN
        #PID.HMI.ManualSetpoint := #PID.HMI.TotalOutput;
    END_IF;
    IF #PID.HMI.HMIAuto THEN
        #PID.HMI.AutoSetpoint := #PID.InPut.SetpointValue;
    END_IF;
    IF #PID.HMI.HMISemiAuto THEN
        #PID.HMI.SemiAutoSetpoint := #PID.InPut.SetpointValue;
    END_IF;
    
END_REGION

REGION 设定值赋值
    
    IF #PID.HMI.Manual_DO THEN
        #PID.Temp.OutputTemp := #PID.HMI.ManualSetpoint;
        #PID.HMI.TotalOutput := #PID.HMI.ManualSetpoint;
        // 在手动模式下保持积分项，防止切换回自动时产生冲击
        #PID.Static.IntegralTerm := #PID.Static.IntegralTerm; // 保持不变
        #PID.OutPut.ControllerActive := 0;
    ELSIF
        #PID.HMI.SemiAuto_DO THEN
        #PID.InPut.SetpointValue := #PID.HMI.SemiAutoSetpoint;
        #PID.OutPut.ControllerActive := 1;
    ELSIF
        #PID.HMI.Auto_DO THEN
        #PID.InPut.SetpointValue := #PID.HMI.AutoSetpoint;
        #PID.OutPut.ControllerActive := 1;
    END_IF;
    
END_REGION

REGION 初始化
    
    IF #PID.Static.FirstScan OR #PID.HMI.HMIReset THEN
        #PID.OutPut.Output := 0.0;
        #PID.OutPut.Error := 0.0;
        #PID.OutPut.Proportional := 0.0;
        #PID.OutPut.Integral := 0.0;
        #PID.OutPut.Derivative := 0.0;
        #PID.OutPut.FeedforwardOutput := 0.0;
        #PID.Static.PrevError := 0.0;
        #PID.Static.PrevPrevError := 0.0;
        #PID.Static.LastOutput := 0.0;
        #PID.OutPut.IncrementalChange := 0.0;
        // #PID.Static.LastFeedforwardInput := 0.0;
        // #PID.Static.FeedforwardRateLimit := 0.0;
        #PID.Static.FeedforwardDelta := 0.0;
        #PID.Static.FirstScan := FALSE;
        
        // 设置初始方向
        IF #PID.HMI.ControllerDirection = 0 THEN
            #PID.Static.DirectionSign := 1.0;  // 正作用
        ELSIF
            #PID.HMI.ControllerDirection = 1 THEN
            #PID.Static.DirectionSign := -1.0; // 反作用
        END_IF;
        
        IF #PID.HMI.HMIReset THEN
            RETURN;  // 重置时立即返回，不执行后续计算
        END_IF;
    END_IF;
    // 时间处理
    #PID.Static.DeltaTime := #PID.InPut.ScanTime / 1000.0;
    
END_REGION

REGION PID计算
    
    IF #PID.OutPut.ControllerActive THEN
        // 根据作用方向计算当前误差 e(t) = Direction * (SP - PV)
        IF ABS(#PID.InPut.SetpointValue - #PID.HMI.ProcessValue) <= #PID.InPut.DeadValue THEN
            #PID.Temp.ErrorTemp := 0; // 死区设置
        ELSE
            #PID.Temp.ErrorTemp := #PID.Static.DirectionSign * (#PID.InPut.SetpointValue - #PID.HMI.ProcessValue);
        END_IF;
        #PID.OutPut.Error := #PID.Temp.ErrorTemp;
        
        // 计算积分系数
        #PID.Temp.Ki := 0.0;
        IF #PID.HMI.Ti > 0.0 AND #PID.Static.DeltaTime > 0.0 THEN
            #PID.Temp.Ki := #PID.HMI.Kp * #PID.Static.DeltaTime / #PID.HMI.Ti;
        END_IF;
        
        // 计算微分系数
        #PID.Temp.Kd := 0.0;
        IF #PID.HMI.Td > 0.0 AND #PID.Static.DeltaTime > 0.0 THEN
            #PID.Temp.Kd := #PID.HMI.Kp * #PID.HMI.Td / #PID.Static.DeltaTime;
        END_IF;
        
        // 计算误差变化量
        #PID.Temp.DeltaError := #PID.Temp.ErrorTemp - #PID.Static.PrevError;
        #PID.Temp.Delta2Error := #PID.Temp.ErrorTemp - 2 * #PID.Static.PrevError + #PID.Static.PrevPrevError;
        
        // 增量式PID公式: Δu(k) = Kp*(e(k)-e(k-1)) + Ki*e(k) + Kd*(e(k)-2e(k-1)+e(k-2))
        #PID.Temp.IncrementalTemp := #PID.HMI.Kp * #PID.Temp.DeltaError + #PID.Temp.Ki * #PID.Temp.ErrorTemp + #PID.Temp.Kd * #PID.Temp.Delta2Error;
        
        // 前馈控制计算
        IF #PID.InPut.EnableFeedforward THEN
            // 计算前馈输入的变化量（增量式前馈）
            #PID.Static.FeedforwardDelta := #PID.InPut.FeedforwardInput - #PID.Static.LastFeedforwardInput;
            #PID.Static.LastFeedforwardInput := #PID.InPut.FeedforwardInput;
            
            // 前馈变化率限制(不使用外部前馈处理程序时使用)，确保前馈输入的变化不会超过每秒±5单位的速率限制
            // #PID.Static.FeedforwardRateLimit := #PID.Static.FeedforwardRateLimit +
            // LIMIT(MN := - #PID.InPut.IncrementalMax * 0.5, IN := #PID.Static.FeedforwardDelta, MX := #PID.InPut.IncrementalMax * 0.5);
            
            // 根据前馈类型计算前馈输出
            CASE #PID.InPut.FeedforwardType OF
                0: // 加法前馈
                    // #PID.Temp.FeedforwardTemp := #PID.InPut.FeedforwardGain * #PID.Static.FeedforwardRateLimit; // 不使用外部前馈处理程序时使用
                    #PID.Temp.FeedforwardTemp := #PID.InPut.FeedforwardGain * #PID.Static.FeedforwardDelta;
                    
                1: // 乘法前馈
                    // #PID.Temp.FeedforwardTemp := #PID.Temp.IncrementalTemp * #PID.InPut.FeedforwardGain * #PID.Static.FeedforwardRateLimit / 100.0; // 不使用外部前馈处理程序时使用
                    #PID.Temp.FeedforwardTemp := #PID.Temp.IncrementalTemp * #PID.InPut.FeedforwardGain * #PID.Static.FeedforwardDelta / 100.0;
                    
                ELSE: // 默认加法前馈
                    // #PID.Temp.FeedforwardTemp := #PID.InPut.FeedforwardGain * #PID.Static.FeedforwardRateLimit; // 不使用外部前馈处理程序时使用
                    #PID.Temp.FeedforwardTemp := #PID.InPut.FeedforwardGain * #PID.Static.FeedforwardDelta;
                    
            END_CASE;
            
            // 前馈输出限幅
            #PID.Temp.FeedforwardTemp := LIMIT(MN := - #PID.InPut.IncrementalMax * 0.8, IN := #PID.Temp.FeedforwardTemp, MX := #PID.InPut.IncrementalMax * 0.8);
            #PID.OutPut.FeedforwardOutput := #PID.Temp.FeedforwardTemp;
            
            // 总增量 = PID增量 + 前馈增量
            #PID.Temp.IncrementalTemp := #PID.Temp.IncrementalTemp + #PID.Temp.FeedforwardTemp;
        ELSE
            #PID.OutPut.FeedforwardOutput := 0.0;
        END_IF;
        
        // 限制增量变化幅度
        IF #PID.Temp.IncrementalTemp > #PID.InPut.IncrementalMax THEN
            #PID.Temp.IncrementalTemp := #PID.InPut.IncrementalMax;
        ELSIF #PID.Temp.IncrementalTemp < - #PID.InPut.IncrementalMax THEN
            #PID.Temp.IncrementalTemp := - #PID.InPut.IncrementalMax;
        END_IF;
        #PID.OutPut.IncrementalChange := #PID.Temp.IncrementalTemp;
        
        // 计算新输出值
        #PID.Temp.OutputTemp := #PID.Static.LastOutput + #PID.Temp.IncrementalTemp;
    END_IF;
    // 输出限幅和抗积分饱和处理
    IF #PID.Temp.OutputTemp > #PID.InPut.OutputMax THEN
        #PID.Temp.OutputTemp := #PID.InPut.OutputMax;
        // 抗积分饱和: 当输出饱和时，停止积分作用
        // 对于增量式PID，这通过限制下一次的积分项实现
        // #PID.OutPut.IncrementalChange := #PID.InPut.OutputMax - #PID.Static.LastOutput;
    ELSIF
        #PID.Temp.OutputTemp < #PID.InPut.OutputMin THEN
        #PID.Temp.OutputTemp := #PID.InPut.OutputMin;
        // 抗积分饱和: 当输出饱和时，停止积分作用
        // #PID.OutPut.IncrementalChange := #PID.InPut.OutputMin - #PID.Static.LastOutput;
    END_IF;
    
    #PID.OutPut.Output := #PID.Temp.OutputTemp;
    #PID.HMI.TotalOutput := #PID.Temp.OutputTemp;
    #PID.Static.LastOutput := #PID.Temp.OutputTemp;
    
    // 保存误差历史供下次使用
    #PID.Static.PrevPrevError := #PID.Static.PrevError;
    #PID.Static.PrevError := #PID.Temp.ErrorTemp;
    
    // 计算各项输出(用于显示和调试)
    #PID.OutPut.Proportional := #PID.HMI.Kp * #PID.Temp.DeltaError;
    #PID.OutPut.Integral := #PID.Temp.Ki * #PID.Temp.ErrorTemp;
    #PID.OutPut.Derivative := #PID.Temp.Kd * #PID.Temp.Delta2Error;
    
    // 更新状态
    #PID.OutPut.DirectionStatus := #PID.HMI.ControllerDirection;
    
END_REGION

REGION 辅助功能
    
    // 按钮自复位
    #PID.HMI.HMIManual := #PID.HMI.HMIManual AND NOT #PID.Temp.HMIManualReset;
    #PID.HMI.HMISemiAuto := #PID.HMI.HMISemiAuto AND NOT #PID.Temp.HMISemiAutoReset;
    #PID.HMI.HMIAuto := #PID.HMI.HMIAuto AND NOT #PID.Temp.HMIAutoReset;
    // #PID.HMI.HMIReset := #PID.HMI.HMIReset AND NOT #PID.Temp.HMIResetReset;
    
    // 自动生成复位信号
    #PID.Temp.HMIManualReset := #PID.HMI.HMIManual;
    #PID.Temp.HMISemiAutoReset := #PID.HMI.HMISemiAuto;
    #PID.Temp.HMIAutoReset := #PID.HMI.HMIAuto;
    // #PID.Temp.HMIResetReset := #PID.HMI.HMIReset;
    
END_REGION

总结

本文将前馈控制算法应用于增量式PID控制模型中，可根据实际执行器特性，选择位置式PID模型还是增量式PID模型。

改进型增量式PID(基于偏差的微分项改为基于反馈的微分项)
RXXW_Dor的博客
05-19 333
1、CODESYS位置式PIDCODESYS位置式PID(完整ST源代码)_codesys pid功能块-CSDN博客CODESYS增量式PID完整源代码请参看下面文章链接：CODESYS增量式PID功能块(ST完整源代码）_RXXW_Dor的博客-CSDN博客增量式PID的详细算法公式和博途源代码，请参看下面的文章链接：博途1200/1500PLC增量式PID算法(详细SCL代码)_博图scl语言pid增量编码器_RXXW_Dor的博客-CSDN博客。
博途1200/1500PLC Smith预估器(补偿器)算法实现(FB)
RXXW_Dor的博客
07-29 2615
在写这篇文章之前写过一篇"大林控制算法"，大家可以参看下面这篇专栏PLC控制一阶惯性纯滞后系统的大林(Dahlin)算法详解(SCL代码)_RXXW_Dor的博客-CSDN博客在控制系统应用中，纯滞后环节往往是影响系统动态特性的不利因素。工业过程中如钢铁，热工和化工过程中往往会有纯滞后（大延迟）环节。对这类系统，控制器如果设计不当，常常会引起系统的超调和持续振荡。由于纯延迟的存在，使被控量对干扰、控制信号不能即时的反映。............
西门子PLC结构化编程_带前馈控制功能的位置式PID控制器
laohei026的博客
09-10 336
本文介绍了一种优化后的PID控制功能块实现方法，在基础PID控制上增加了手自动无扰切换、前馈控制等高级功能。通过公式推导建立了离散化PID模型，详细阐述了位置式PID和前馈控制的计算原理。程序采用西门子PLC结构化编程，实现了防积分饱和、死区控制、输出限幅等工业应用关键功能，支持手动/半自动/自动三种模式的无扰切换。该方案通过数据类型封装和模块化设计，提高了PID控制器的稳定性和实用性，适用于复杂的工业控制场景。
使用FB41进行PID调整的说明
weixin_40704392的博客
10-30 1696
使用FB41进行PID调整的说明 目前工业自动化水平已成为衡量各行各业现代化水平的一个重要标志。同时，控制理论的发展也经历了古典控制理论、现代控制理论和智能控制理论三个阶段。智能控制的典型实例是模糊全自动洗衣机等。自动控制 系统可分为开环控制系统和闭环控制系统。一个控控制系统包括控制器﹑传感器﹑变送器﹑执行机构﹑输入输出接口。控制器的输出经过输出接口﹑执行机构﹐加到被控系统上﹔控制系统的被控量﹐经过传感器﹐变送器﹐通过输入接口送到控制器。不同的控制系统﹐其传感器﹑变送器﹑执行机构是不一样的
西门子PLC上所使用的软件PID程序
newzhpfree的博客
02-08 2500
西门子PLC PID程序
伺服同步 102 105 750 111报文
qq_25194681的博客
08-22 478
报文750 (Message 750) - 这个报文用于读取过程数据(Process Data)，包括实际位置、速度等信息。这是实时通信的一部分，用于监控驱动器的状态。报文111 (Message 111) - 这个报文通常用于读取状态字(Status Word)。状态字提供了关于驱动器当前状态的信息，例如是否准备好、是否有故障等。报文102 (Message 102) - 报文102通常用于写入控制字(Control Word)，它包含了启动、停止、方向以及其他控制指令，用来控制驱动器的动作。
面向对象技术在开放式数控中的应用
沥泉博客
06-03 9526
数控（NC，Numerical Control）是一种用数字化的信息（数字、字母和符号）对某一工作过程（如加工、测量、装配等）进行可编程的自动控制技术。数控系统（Numerical Control System）是实现数控技术相关功能的软硬件集成的系统，是数控技术的载体。数控机床（Numerical Control Machine Tools）是采用数字控制技术对机床的加工过程
51c大模型~合集158
whaosoft~aiotの开发板商城
07-23 885
举个例子就是，如果想要教一个徒弟同时会拳脚功夫，但师傅一次又教不了，那就同时教两个徒弟，一个学打拳，一个学踢腿，然后让他们俩天天互相打，打着打着两个就都会拳脚功夫了。最终，这个多模态模型就完成了，不仅可以完成简单的文本转语音，还能实现更复杂的任务，比如让它写一首歌并唱出来，再加上配乐。然后要让模型很好地理解和生成声音，就需要利用模型的文本空间，将语音的语义尽量地映射回文本，当中需要大量的数据支持。传统的语音和文本模型之间相互独立，李沐老师就想，欸，能不能将两者结合起来，直接让LLM用语音进行沟通。
加入前馈PID控制，则PLC的梯形图该是如何
03-19
- 调用PLC内置PID指令或自定义增量式PID算法： ```ladder |--[PID D100 PV D110]--| //D100为PID参数区，PV为过程变量，D110为PID输出 ``` ##### **步骤4：叠加前馈与PID输出** - 将前馈量与PID输出叠加，并进行...
S7-200 PLC伺服控制：工业自动化中的伺服电机控制技术揭秘
![伺服控制](https://robu.in/wp-content/uploads/2020/04/Servo-motor-constructons.png)...通过基于位置与速度控制的实际应用案例，展示了S7-200 PLC伺服控制技术在自动化领域的强大能力。此外，本文还探讨了多轴同步
【PLC编程进阶】：西门子S7-1200与ASDA-B2伺服的高效编程指南
![【PLC编程进阶】：西门子S7-1200与...本文系统性地介绍了西门子S7-1200 PLC和ASDA-B2伺服驱动器的基本知识、编程理论与实践、以及在整合应用中的编程实践。文中首先对PLC的基础编程理论进行了深入分析，包括编程语言
字体文件ttf裁剪工具
09-11
1、点开FontSubsetGUI.exe 2、Source Font选择为你自己所需的源字体库。 3、New Font为你自己想保存导出的字体库。 4、Char List为对照文件，需要txt格式，可将所用到的所有字符放入这个txt，然后选择这个txt文档。 5、Encoding为格式设置，一般UTF-8即可，若不知道，可不指定。 6、点击Proceed，即可导出。 注意，只能ttf文件
Coze/视频历史人物的一生工作流
09-11
文件编号：co0048 Coze工作流汇总 https://datayang.blog.csdn.net/article/details/124779452 工作流使用方法 https://datayang.blog.csdn.net/article/details/142167278 更多工具介绍 项目源码搭建介绍： 《我的AI工具箱Tauri+Django开源git项目介绍和使用》https://datayang.blog.csdn.net/article/details/146156817 图形桌面工具使用教程： 《我的AI工具箱Tauri+Django环境开发，支持局域网使用》https://datayang.blog.csdn.net/article/details/141897688
【scratch2.0少儿编程-游戏原型-动画-项目源码】3[猫和老鼠].zip
09-11
资源说明： 1：本资料仅用作交流学习参考，请切勿用于商业用途。 2：一套精品实用scratch2.0少儿编程游戏、动画源码资源，无论是入门练手还是项目复用都超实用，省去重复开发时间，让开发少走弯路！ 更多精品资源请访问 https://blog.csdn.net/ashyyyy/article/details/146464041
现有svm识别模型，根据16000Hz，单声道音频判断是否为“到”
09-11
现有svm识别模型，根据16000Hz，单声道音频判断是否为“到”
基于C控制台开发的航空客运订票系统_数据结构课程设计作业_单链表存储航班数据_用户界面与管理员界面分离_查询航班_搜索航班_订票_退票_增加删除航班信息_浏览顾客信息_wind.zip
09-11
基于C控制台开发的航空客运订票系统_数据结构课程设计作业_单链表存储航班数据_用户界面与管理员界面分离_查询航班_搜索航班_订票_退票_增加删除航班信息_浏览顾客信息_wind.zip
tapo测试集应用.7z
09-11
tapo测试集应用.7z
基于微信小程序的大学生科技竞赛管理系统_项目极简说明本系统通过微信小程序与SpringBoot框架实现大学生科技竞赛的线上全流程管理包含学生报名主办方评分管理员审核及信息统.zip
最新发布
09-11
基于微信小程序的大学生科技竞赛管理系统_项目极简说明本系统通过微信小程序与SpringBoot框架实现大学生科技竞赛的线上全流程管理包含学生报名主办方评分管理员审核及信息统.zip
【scratch3.0少儿编程-游戏原型-动画-项目源码】时空穿越源代码.zip
09-11
资源说明： 1：本资料仅用作交流学习参考，请切勿用于商业用途。 2：一套精品实用scratch3.0少儿编程游戏、动画源码资源，无论是入门练手还是项目复用都超实用，省去重复开发时间，让开发少走弯路！ 更多精品资源请访问 https://blog.csdn.net/ashyyyy/article/details/146464041
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值