字节码文件由五部分组成，分别是基础信息、常量池、字段、方法、属性。
案例：
public class Main implements InterfaceA {
public static final String HELLO = "hello";
public static final String WORLD = "world";
public static final String HELLO2 = "hello";
public static final String hello = "hello";
public void methodA() {
String all = HELLO + WORLD;
System.out.println(all);
}
public static void main(String[] args) {
Main main = new Main();
main.methodA();
}
}
以下将以上述内容为案例，说明字节码文件的五部分内容。
基础信息
基础信息中包含魔数、字节码文件对应的 Java 版本号、访问标识（public、final 等等）及父类和接口。
- 魔数：魔数用于标识当前文件是 java 语言的字节码文件（.class），其固定值为
0xCAFEBABE。 - 主/次版本号：主/次版本号确定当前字节码文件对应的 JDK 版本号，用于判断当前字节码文件的版本与运行该字节码文件的 JDK 的版本是否兼容。其中，主版本号用来标识大版本号，例如 JDK1.0-1.1 使用了 45.0-45.3，JDK1.2 是 46 之后每升级一个大版本就加 1；副版本号是当主版本号相同时作为区分不同版本的标识，一般只需要关心主版本号。
使用 jclasslib 打开 Main.class 查看一般信息：
常量池
常量池中保存字符串常量、类或接口名、字段名，这些内容主要在字节码指令中使用。常量池可以避免内容重复定义，减小 .class 文件的大小，从而达到节省空间的目的。
例如，使用 jclasslib 打开 Main.class 查看常量池中 String 类型的常量发现只有 3 个：
打开这 3 个常量信息，发现它们的值分别是 helloworld、hello 和 world：
String 类型的常量只有 3 个而不是 5 个的原因是成员变量 HELLO、HELLO2 与 hello 都指向常量池中的同一个值 hello。
需要注意的是，类实现的接口信息也存放于常量池中：
字段
字段中包含当前类或接口声明的字段信息。
使用 jclasslib 打开 Main.class 可以查看定义了 4 个字段信息：
而其中 3 个指向了常量池中的同一个值为 hello 的地址：
即上文提到的常量池避免内容重复定义。
方法
方法中包含当前类或接口声明的方法信息。
使用 jclasslib 打开 Main.class 查看方法信息：
属性
属性中包含类的属性，比如源码的文件名、内部类的列表等。
使用 jclasslib 打开 Main.class 查看属性信息：
字节码文件内容说明案例
以上述 Main.java 编译后的字节码文件 Main.class 为例，通过 javap -v Main.class > Main.class.txt 得到 Main.class.txt。
Main.class.txt 内容如下：
Classfile /home/wftapp/test/Main.class
Last modified Aug 6, 2025; size 814 bytes
MD5 checksum ccde33e85e9b2fe106990c9f5c38f6bc
Compiled from "Main.java"
public class Main implements InterfaceA
minor version: 0
major version: 52
flags: ACC_PUBLIC, ACC_SUPER
Constant pool:
#1 = Methodref #8.#33 // java/lang/Object."<init>":()V
#2 = Class #34 // Main
#3 = String #35 // helloworld
#4 = Fieldref #36.#37 // java/lang/System.out:Ljava/io/PrintStream;
#5 = Methodref #38.#39 // java/io/PrintStream.println:(Ljava/lang/String;)V
#6 = Methodref #2.#33 // Main."<init>":()V
#7 = Methodref #2.#40 // Main.methodA:()V
#8 = Class #41 // java/lang/Object
#9 = Class #42 // InterfaceA
#10 = Utf8 HELLO
#11 = Utf8 Ljava/lang/String;
#12 = Utf8 ConstantValue
#13 = String #17 // hello
#14 = Utf8 WORLD
#15 = String #43 // world
#16 = Utf8 HELLO2
#17 = Utf8 hello
#18 = Utf8 <init>
#19 = Utf8 ()V
#20 = Utf8 Code
#21 = Utf8 LineNumberTable
#22 = Utf8 LocalVariableTable
#23 = Utf8 this
#24 = Utf8 LMain;
#25 = Utf8 methodA
#26 = Utf8 all
#27 = Utf8 main
#28 = Utf8 ([Ljava/lang/String;)V
#29 = Utf8 args
#30 = Utf8 [Ljava/lang/String;
#31 = Utf8 SourceFile
#32 = Utf8 Main.java
#33 = NameAndType #18:#19 // "<init>":()V
#34 = Utf8 Main
#35 = Utf8 helloworld
#36 = Class #44 // java/lang/System
#37 = NameAndType #45:#46 // out:Ljava/io/PrintStream;
#38 = Class #47 // java/io/PrintStream
#39 = NameAndType #48:#49 // println:(Ljava/lang/String;)V
#40 = NameAndType #25:#19 // methodA:()V
#41 = Utf8 java/lang/Object
#42 = Utf8 InterfaceA
#43 = Utf8 world
#44 = Utf8 java/lang/System
#45 = Utf8 out
#46 = Utf8 Ljava/io/PrintStream;
#47 = Utf8 java/io/PrintStream
#48 = Utf8 println
#49 = Utf8 (Ljava/lang/String;)V
{
public static final java.lang.String HELLO;
descriptor: Ljava/lang/String;
flags: ACC_PUBLIC, ACC_STATIC, ACC_FINAL
ConstantValue: String hello
public static final java.lang.String WORLD;
descriptor: Ljava/lang/String;
flags: ACC_PUBLIC, ACC_STATIC, ACC_FINAL
ConstantValue: String world
public static final java.lang.String HELLO2;
descriptor: Ljava/lang/String;
flags: ACC_PUBLIC, ACC_STATIC, ACC_FINAL
ConstantValue: String hello
public static final java.lang.String hello;
descriptor: Ljava/lang/String;
flags: ACC_PUBLIC, ACC_STATIC, ACC_FINAL
ConstantValue: String hello
public Main();
descriptor: ()V
flags: ACC_PUBLIC
Code:
stack=1, locals=1, args_size=1
0: aload_0
1: invokespecial #1 // Method java/lang/Object."<init>":()V
4: return
LineNumberTable:
line 1: 0
LocalVariableTable:
Start Length Slot Name Signature
0 5 0 this LMain;
public void methodA();
descriptor: ()V
flags: ACC_PUBLIC
Code:
stack=2, locals=2, args_size=1
0: ldc #3 // String helloworld
2: astore_1
3: getstatic #4 // Field java/lang/System.out:Ljava/io/PrintStream;
6: aload_1
7: invokevirtual #5 // Method java/io/PrintStream.println:(Ljava/lang/String;)V
10: return
LineNumberTable:
line 12: 0
line 13: 3
line 14: 10
LocalVariableTable:
Start Length Slot Name Signature
0 11 0 this LMain;
3 8 1 all Ljava/lang/String;
public static void main(java.lang.String[]);
descriptor: ([Ljava/lang/String;)V
flags: ACC_PUBLIC, ACC_STATIC
Code:
stack=2, locals=2, args_size=1
0: new #2 // class Main
3: dup
4: invokespecial #6 // Method "<init>":()V
7: astore_1
8: aload_1
9: invokevirtual #7 // Method methodA:()V
12: return
LineNumberTable:
line 17: 0
line 18: 8
line 19: 12
LocalVariableTable:
Start Length Slot Name Signature
0 13 0 args [Ljava/lang/String;
8 5 1 main LMain;
}
SourceFile: "Main.java"
Main.class.txt 的各个组成部分的详细解释如下。
文件基本信息
Classfile /home/wftapp/test/Main.class
Last modified Aug 6, 2025; size 814 bytes
MD5 checksum ccde33e85e9b2fe106990c9f5c38f6bc
Compiled from "Main.java"
- Classfile：指定了字节码文件的路径。
- Last modified：文件的最后修改时间。
- size：文件的大小，单位是字节。
- MD5 checksum：文件的 MD5 校验和，用于验证文件的完整性。
- Compiled from：该字节码文件是由哪个 Java 源文件编译而来的。
类的基本信息
public class Main implements InterfaceA
minor version: 0
major version: 52
flags: ACC_PUBLIC, ACC_SUPER
- public class Main implements InterfaceA：声明了一个公共类
Main，该类实现了接口InterfaceA。 - minor version：次要版本号，这里是 0。
- major version：主要版本号，52 对应 Java 8。
- flags：类的访问标志，
ACC_PUBLIC表示该类是公共的，ACC_SUPER是一个历史遗留标志，现代 Java 编译器都会设置这个标志。
常量池
Constant pool:
#1 = Methodref #8.#33 // java/lang/Object."<init>":()V
#2 = Class #34 // Main
#3 = String #35 // helloworld
...
常量池是字节码文件的重要组成部分，它包含了类、方法、字段等的符号引用和字面量。每个常量都有一个唯一的索引，通过这些索引可以在字节码中引用常量。例如，#1 是一个方法引用，指向 java/lang/Object 类的构造方法。
字段信息
{
public static final java.lang.String HELLO;
descriptor: Ljava/lang/String;
flags: ACC_PUBLIC, ACC_STATIC, ACC_FINAL
ConstantValue: String hello
public static final java.lang.String WORLD;
...
声明了几个公共静态常量字段，如 HELLO、WORLD 等。
- descriptor：字段的类型描述符，
Ljava/lang/String;表示该字段是String类型。 - flags：字段的访问标志，
ACC_PUBLIC表示公共的，ACC_STATIC表示静态的，ACC_FINAL表示常量。 - ConstantValue：常量字段的值，这里
HELLO的值是"hello"。
构造方法
public Main();
descriptor: ()V
flags: ACC_PUBLIC
Code:
stack=1, locals=1, args_size=1
0: aload_0
1: invokespecial #1 // Method java/lang/Object."<init>":()V
4: return
LineNumberTable:
line 1: 0
LocalVariableTable:
Start Length Slot Name Signature
0 5 0 this LMain;
- public Main()：公共的无参构造方法。
- descriptor：方法的描述符，
()V表示该方法没有参数，返回值为void。 - flags：方法的访问标志，
ACC_PUBLIC表示公共的。 - Code：方法的字节码指令，这里调用了父类
Object的构造方法。 - LineNumberTable：行号表，用于将字节码指令与源文件的行号对应起来。
- LocalVariableTable：局部变量表，记录了方法中局部变量的信息，这里
this是Main类的实例。
实例方法
public void methodA();
descriptor: ()V
flags: ACC_PUBLIC
Code:
stack=2, locals=2, args_size=1
0: ldc #3 // String helloworld
2: astore_1
3: getstatic #4 // Field java/lang/System.out:Ljava/io/PrintStream;
6: aload_1
7: invokevirtual #5 // Method java/io/PrintStream.println:(Ljava/lang/String;)V
10: return
LineNumberTable:
line 12: 0
line 13: 3
line 14: 10
LocalVariableTable:
Start Length Slot Name Signature
0 11 0 this LMain;
3 8 1 all Ljava/lang/String;
- public void methodA()：公共的实例方法，没有参数，返回值为
void。 - Code：方法的字节码指令，这里将字符串
"helloworld"压入栈，然后调用System.out.println方法打印该字符串。 - LineNumberTable：行号表，将字节码指令与源文件的行号对应。
- LocalVariableTable：局部变量表，记录了方法中局部变量的信息，
this是Main类的实例，all是存储"helloworld"的局部变量。
主方法
public static void main(java.lang.String[]);
descriptor: ([Ljava/lang/String;)V
flags: ACC_PUBLIC, ACC_STATIC
Code:
stack=2, locals=2, args_size=1
0: new #2 // class Main
3: dup
4: invokespecial #6 // Method "<init>":()V
7: astore_1
8: aload_1
9: invokevirtual #7 // Method methodA:()V
12: return
LineNumberTable:
line 17: 0
line 18: 8
line 19: 12
LocalVariableTable:
Start Length Slot Name Signature
0 13 0 args [Ljava/lang/String;
8 5 1 main LMain;
- public static void main(java.lang.String[])：Java 程序的入口方法。
- Code：方法的字节码指令，这里创建了一个
Main类的实例，然后调用该实例的methodA方法。 - LineNumberTable：行号表，将字节码指令与源文件的行号对应。
- LocalVariableTable：局部变量表，记录了方法中局部变量的信息，
args是命令行参数数组，main是Main类的实例。
源文件信息
SourceFile: "Main.java"
指定了该字节码文件对应的源文件名称。
扫一扫
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
