10.1 环境映射的立方体纹理反射

最新推荐文章于 2025-06-01 22:44:45 发布

会思考的猴子

最新推荐文章于 2025-06-01 22:44:45 发布

阅读量282

点赞数 1

分类专栏： Shader

Shader 专栏收录该内容

53 篇文章

订阅专栏

本文详细介绍了一个使用Shader实现的反射效果，通过三个关键步骤：计算反射方向、立方体贴图采样和混合漫反射与反射颜色，展示了如何在Unity中创建动态且真实的反射效果。代码示例清晰地解释了如何调整反射强度，从而在不同的光照条件下达到理想的效果。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

代码来源于 shader 入门精要

其实关键的代码就三句

1.根据视角方向和法线求出反射反向

o.worldRef1 = reflect(-o.worldViewDir,o.worldNormal);

2.对 _Cubemap 进行采样

fixed3 reflection = texCUBE(_Cubemap,i.worldRef1).rgb * _ReflectColor;

3. 当_ReflectAmount从 0 到 1 变化就相当去 diffuse 到 reflection的变化,lerp操作

fixed3 color = ambient + lerp(diffuse,reflection,_ReflectAmount)*atten;

Shader "Chapter10/ReflectionShader"
{
	Properties
	{
		_Color("Main Color",Color) = (1,1,1,1)
		_ReflectColor("Reflect Color",Color) = (1,1,1,1)
		_ReflectAmount("Reflect Amount",Range(0,1)) = 1
		_Cubemap("Cube Map",Cube) = "_Skybox"{}
	}
	SubShader
	{
		Tags { "RenderType"="Opaque" "Queue"="Geometry"}

		Pass
		{
			Tags{"LightMode"="ForwardBase"}
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			
			#include "Lighting.cginc"
			#include "AutoLight.cginc"

			struct a2v{
				float4 vertex: POSITION;
				float3 normal: NORMAL;
			};

			struct v2f{
				float4 pos: SV_POSITION;
				fixed3 worldNormal:TEXCOORD;
				fixed3 worldPos:TEXCOORD1;
				fixed3 worldViewDir: TEXCOORD2;
				fixed3 worldRef1:TEXCOORD3;
				SHADOW_COORDS(4)
			};

			fixed4 _Color;
			samplerCUBE _Cubemap;
			fixed4 _ReflectColor;
			fixed _ReflectAmount;
			
			v2f vert (a2v v)
			{
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				o.worldNormal = UnityObjectToWorldNormal(v.normal);
				o.worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;
				o.worldViewDir = UnityWorldSpaceViewDir(o.worldPos);
				o.worldRef1 = reflect(-o.worldViewDir,o.worldNormal);

				TRANSFER_SHADOW(o);

				return o;
			}
			
			fixed4 frag (v2f i) : SV_Target
			{
				fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
				fixed3 worldViewDir = normalize(i.worldViewDir);

				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

				fixed3 diffuse = _LightColor0.rgb *_Color.rgb* max(0,dot(worldNormal,worldLightDir));

				fixed3 reflection = texCUBE(_Cubemap,i.worldRef1).rgb * _ReflectColor;

				UNITY_LIGHT_ATTENUATION(atten,i,i.worldPos);

				fixed3 color = ambient + lerp(diffuse,reflection,_ReflectAmount)*atten;

				return fixed4(color,1.0);

			}
			ENDCG
		}
	}
	Fallback "Reflective/VertexLit"
}