ios/chrome/app/application_delegate/BUILD.gn

# Copyright 2016 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/buildflag_header.gni")
import("//ios/chrome/features.gni")

buildflag_header("ios_enable_metrickit_buildflags") {
  header = "ios_enable_metrickit_buildflags.h"
  flags = [ "IOS_ENABLE_METRICKIT=$ios_enable_metrickit" ]
}

source_set("application_delegate") {
  sources = [
    "memory_warning_helper.h",
    "memory_warning_helper.mm",
  ]
  deps = [
    "//base",
    "//ios/chrome/browser/crash_report",
    "//ios/chrome/browser/metrics",
  ]
  libs = [ "Foundation.framework" ]

  configs += [ "//build/config/compiler:enable_arc" ]
}

source_set("unit_tests") {
  configs += [ "//build/config/compiler:enable_arc" ]
  testonly = true
  sources = [
    "app_state_unittest.mm",
    "memory_warning_helper_unittest.mm",
    "metric_kit_subscriber_unittest.mm",
    "metrics_mediator_unittest.mm",
    "url_opener_unittest.mm",
    "user_activity_handler_unittest.mm",
  ]
  deps = [
    ":application_delegate",
    ":application_delegate_internal",
    ":metric_kit_subscriber",
    ":tab_opening",
    ":test_support",
    "//base",
    "//base/test:test_support",
    "//components/handoff",
    "//components/metrics",
    "//ios/chrome/app",
    "//ios/chrome/app:app_internal",
    "//ios/chrome/app:mode",
    "//ios/chrome/app/intents",
    "//ios/chrome/app/spotlight",
    "//ios/chrome/app/startup",
    "//ios/chrome/browser",
    "//ios/chrome/browser/browser_state:test_support",
    "//ios/chrome/browser/crash_report",
    "//ios/chrome/browser/device_sharing",
    "//ios/chrome/browser/geolocation",
    "//ios/chrome/browser/main:public",
    "//ios/chrome/browser/main:test_support",
    "//ios/chrome/browser/metrics",
    "//ios/chrome/browser/ntp_snippets",
    "//ios/chrome/browser/signin",
    "//ios/chrome/browser/signin:test_support",
    "//ios/chrome/browser/tabs",
    "//ios/chrome/browser/u2f",
    "//ios/chrome/browser/ui/commands",
    "//ios/chrome/browser/ui/main",
    "//ios/chrome/browser/ui/main:scene",
    "//ios/chrome/browser/ui/main/test",
    "//ios/chrome/browser/ui/safe_mode",
    "//ios/chrome/browser/ui/settings",
    "//ios/chrome/browser/ui/settings:settings_root",
    "//ios/chrome/browser/url_loading",
    "//ios/chrome/browser/web:tab_id_tab_helper",
    "//ios/chrome/browser/web_state_list",
    "//ios/chrome/browser/web_state_list:test_support",
    "//ios/chrome/test:test_support",
    "//ios/chrome/test/ocmock",
    "//ios/public/provider/chrome/browser:test_support",
    "//ios/public/provider/chrome/browser/distribution",
    "//ios/public/provider/chrome/browser/user_feedback:test_support",
    "//ios/testing:block_swizzler",
    "//ios/testing:ocmock_support",
    "//ios/web",
    "//ios/web/public/test",
    "//ios/web/public/test/fakes",
    "//net:test_support",
    "//testing/gtest",
    "//third_party/breakpad:client",
    "//third_party/ocmock",
    "//ui/base",
    "//url",
  ]
  libs = [ "CoreSpotlight.framework" ]
}

source_set("tab_opening") {
  configs += [ "//build/config/compiler:enable_arc" ]
  sources = [
    "tab_opening.h",
    "tab_switching.h",
  ]
  deps = [
    "//base",
    "//ios/chrome/app",
    "//ios/chrome/app:mode",
    "//ios/chrome/browser/main:public",
    "//ui/base",
  ]
  libs = [
    "CoreSpotlight.framework",
    "UIKit.framework",
  ]
}

source_set("metric_kit_subscriber") {
  configs += [ "//build/config/compiler:enable_arc" ]
  sources = [
    "metric_kit_subscriber.h",
    "metric_kit_subscriber.mm",
    "metric_kit_subscribing_util.h",
    "metric_kit_subscribing_util.mm",
  ]
  libs = [ "MetricKit.framework" ]
  deps = [
    ":ios_enable_metrickit_buildflags",
    "//base",
  ]
}

source_set("application_delegate_internal") {
  configs += [ "//build/config/compiler:enable_arc" ]
  sources = [
    "app_state.h",
    "app_state.mm",
    "browser_launcher.h",
    "metrics_mediator.h",
    "metrics_mediator.mm",
    "startup_information.h",
    "tab_switching.h",
    "url_opener.h",
    "url_opener.mm",
    "user_activity_handler.h",
    "user_activity_handler.mm",
  ]
  deps = [
    ":application_delegate",
    ":ios_enable_metrickit_buildflags",
    ":tab_opening",
    "//base",
    "//build:branding_buildflags",
    "//components/crash/core/common",
    "//components/feature_engagement",
    "//components/handoff",
    "//components/metrics",
    "//components/prefs",
    "//components/search_engines",
    "//components/ukm/ios:features",
    "//ios/chrome/app",
    "//ios/chrome/app:mode",
    "//ios/chrome/app/intents",
    "//ios/chrome/app/spotlight",
    "//ios/chrome/app/startup",
    "//ios/chrome/browser",
    "//ios/chrome/browser/browser_state",
    "//ios/chrome/browser/crash_report",
    "//ios/chrome/browser/device_sharing",
    "//ios/chrome/browser/feature_engagement",
    "//ios/chrome/browser/geolocation",
    "//ios/chrome/browser/main:public",
    "//ios/chrome/browser/metrics",
    "//ios/chrome/browser/metrics:metrics_internal",
    "//ios/chrome/browser/net",
    "//ios/chrome/browser/ntp_snippets:ntp_snippets",
    "//ios/chrome/browser/search_engines",
    "//ios/chrome/browser/signin",
    "//ios/chrome/browser/tabs",
    "//ios/chrome/browser/u2f",
    "//ios/chrome/browser/ui/authentication",
    "//ios/chrome/browser/ui/commands",
    "//ios/chrome/browser/ui/main",
    "//ios/chrome/browser/ui/main:scene",
    "//ios/chrome/browser/ui/safe_mode",
    "//ios/chrome/browser/ui/util",
    "//ios/chrome/browser/ui/util:multiwindow_util",
    "//ios/chrome/browser/url_loading",
    "//ios/chrome/browser/web:tab_id_tab_helper",
    "//ios/chrome/browser/web_state_list",
    "//ios/chrome/browser/web_state_list:agents",
    "//ios/chrome/common/app_group:main_app",
    "//ios/net",
    "//ios/public/provider/chrome/browser",
    "//ios/public/provider/chrome/browser/distribution",
    "//ios/public/provider/chrome/browser/user_feedback",
    "//ios/web",
    "//net",
    "//ui/base",
    "//url",
  ]
  if (ios_enable_metrickit) {
    deps += [ ":metric_kit_subscriber" ]
  }
  libs = [
    "CoreSpotlight.framework",
    "UIKit.framework",
  ]
  allow_circular_includes_from = [
    "//ios/chrome/browser/url_loading",
    "//ios/chrome/browser/ui/main:scene",
  ]
}

source_set("test_support") {
  configs += [ "//build/config/compiler:enable_arc" ]
  testonly = true
  sources = [
    "app_state_testing.h",
    "fake_startup_information.h",
    "fake_startup_information.mm",
    "metrics_mediator_testing.h",
    "mock_tab_opener.h",
    "mock_tab_opener.mm",
  ]
  deps = [
    ":application_delegate_internal",
    ":tab_opening",
    "//base",
    "//base/test:test_support",
    "//ios/chrome/app",
    "//ios/chrome/app:app_internal",
    "//ios/chrome/app:mode",
    "//ios/chrome/browser",
    "//ios/chrome/browser/url_loading",
    "//net",
    "//ui/base",
    "//url",
  ]
  libs = [ "UIKit.framework" ]
}