1 files changed, 80 insertions, 0 deletions
diff --git a/qt-bundle/qt.pro b/qt-bundle/qt.pro
new file mode 100644
index 0000000..10baf7b
--- /dev/null
+++ b/qt-bundle/qt.pro
@@ -0,0 +1,80 @@
+TEMPLATE      = subdirs
+
+module_qtkernel.subdir = $$IN_PWD/qtkernel
+module_qtkernel.target = module-qtkernel
+
+module_qtsvg.subdir = $$IN_PWD/qtsvg
+module_qtsvg.target = module-qtsvg
+module_qtsvg.depends = module_qtkernel
+
+module_phonon.subdir = $$IN_PWD/phonon
+module_phonon.target = module-phonon
+module_phonon.depends = module_qtkernel
+
+module_qtmultimedia.subdir = $$IN_PWD/qtmultimedia
+module_qtmultimedia.target = module-qtmultimedia
+module_qtmultimedia.depends = module_qtkernel
+
+module_qtxmlpatterns.subdir = $$IN_PWD/qtxmlpatterns
+module_qtxmlpatterns.target = module-qtxmlpatterns
+module_qtxmlpatterns.depends = module_qtkernel
+
+module_qtscript.subdir = $$IN_PWD/qtscript
+module_qtscript.target = module-qtscript
+module_qtscript.depends = module_qtkernel
+
+module_qtquick.subdir = $$IN_PWD/qtquick
+module_qtquick.target = module-qtquick
+module_qtquick.depends = module_qtkernel module_qtscript module_qtsvg module_qtxmlpatterns
+
+module_qt3support.subdir = $$IN_PWD/qt3support
+module_qt3support.target = module-qt3support
+module_qt3support.depends = module_qtkernel
+
+module_qtwebkit.file = qtwebkit.pri
+module_qtwebkit.makefile = Makefile.qtwebkit
+module_qtwebkit.depends = module_qtkernel module_qtscript module_qtquick module_phonon
+# The qtwebkit subdir does not follow the "module-*" scheme, so make our own target that does.
+module_qtwebkit_target.target = module-qtwebkit
+module_qtwebkit_target.commands =
+module_qtwebkit_target.depends = sub-qtwebkit-pri
+QMAKE_EXTRA_TARGETS += module_qtwebkit_target
+
+qtwebkit_examples_and_demos.subdir = $$IN_PWD/qtwebkit-examples-and-demos
+qtwebkit_examples_and_demos.target = qtwebkit-examples-and-demos
+qtwebkit_examples_and_demos.depends = module_qtwebkit
+
+module_qttools.subdir = $$IN_PWD/qttools
+module_qttools.target = module-qttools
+module_qttools.depends = module_qtkernel module_qtscript module_qtquick module_qt3support module_qtwebkit
+win32:module_qttools.depends += module_activeqt
+
+module_qttranslations.subdir = $$IN_PWD/qttranslations
+module_qttranslations.target = module-qttranslations
+module_qttranslations.depends = module_qttools
+
+module_qtdoc.subdir = $$IN_PWD/qtdoc
+module_qtdoc.target = module-qtdoc
+module_qtdoc.depends = module_qtquick module_qttools #for the demos and QtHelp
+
+module_activeqt.subdir = $$IN_PWD/activeqt
+module_activeqt.target = module-activeqt
+module_activeqt.depends = module_qtkernel
+
+
+SUBDIRS       = \
+                module_qtkernel \
+                module_qtsvg \
+                module_phonon \
+                module_qtxmlpatterns \
+                module_qtscript \
+                module_qtquick \
+                module_qt3support \
+                module_qtwebkit \
+                module_qtmultimedia \
+                module_qttools \
+                module_qttranslations \
+                module_qtdoc \
+                qtwebkit_examples_and_demos \
+
+win32:SUBDIRS += module_activeqt