Remove "2" from Qt Quick Controls directories

Qt Quick Controls 2 was named that way because it was a follow-up to
Qt Quick Controls 1.x. Now that Qt Quick Controls 1 is no longer
supported, we don't need to have "2" in the name. Work on this was
already started for the documentation in
1abdfe5d5a052f2298b7bf657513dfa7e0c66a56.

By doing this renaming a few weeks before feature freeze, it won't
affect the release but still results in as little time possible spent
manually fixing conflicts in cherry-picks from non-LTS releases as a
result of the renaming.

This patch does the following:

- Renames directories.
- Adapts CMakeLists.txt and other files to account for the new paths.

A follow-up patch will handle documentation.

It does not touch library names or other user-facing stuff, as that
will have to be done in Qt 7.

Task-number: QTBUG-95413
Change-Id: I170d8db19033ee71e495ff0c5c1a517a41ed7634
Reviewed-by: Mitch Curtis <[email protected]>

1 files changed, 71 insertions, 0 deletions

diff --git a/src/quickcontrols/basic/DelayButton.qml b/src/quickcontrols/basic/DelayButton.qml
new file mode 100644
index 0000000000..1be4450c69
--- /dev/null
+++ b/src/quickcontrols/basic/DelayButton.qml
@@ -0,0 +1,71 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
+
+import QtQuick
+import QtQuick.Controls.impl
+import QtQuick.Templates as T
+
+T.DelayButton {
+    id: control
+
+    implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
+                            implicitContentWidth + leftPadding + rightPadding)
+    implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
+                             implicitContentHeight + topPadding + bottomPadding)
+
+    padding: 6
+    horizontalPadding: padding + 2
+
+    transition: Transition {
+        NumberAnimation {
+            duration: control.delay * (control.pressed ? 1.0 - control.progress : 0.3 * control.progress)
+        }
+    }
+
+    contentItem: ItemGroup {
+        ClippedText {
+            clip: control.progress > 0
+            clipX: -control.leftPadding + control.progress * control.width
+            clipWidth: (1.0 - control.progress) * control.width
+            visible: control.progress < 1
+
+            text: control.text
+            font: control.font
+            opacity: enabled ? 1 : 0.3
+            color: control.palette.buttonText
+            horizontalAlignment: Text.AlignHCenter
+            verticalAlignment: Text.AlignVCenter
+            elide: Text.ElideRight
+        }
+
+        ClippedText {
+            clip: control.progress > 0
+            clipX: -control.leftPadding
+            clipWidth: control.progress * control.width
+            visible: control.progress > 0
+
+            text: control.text
+            font: control.font
+            opacity: enabled ? 1 : 0.3
+            color: control.palette.brightText
+            horizontalAlignment: Text.AlignHCenter
+            verticalAlignment: Text.AlignVCenter
+            elide: Text.ElideRight
+        }
+    }
+
+    background: Rectangle {
+        implicitWidth: 100
+        implicitHeight: 40
+        color: Color.blend(control.palette.button, control.palette.mid, control.down ? 0.5 : 0.0)
+        border.color: control.palette.highlight
+        border.width: control.visualFocus ? 2 : 0
+
+        PaddedRectangle {
+            padding: control.visualFocus ? 2 : 0
+            width: control.progress * parent.width
+            height: parent.height
+            color: Color.blend(control.palette.dark, control.palette.mid, control.down ? 0.5 : 0.0)
+        }
+    }
+}