Remove "2" from Qt Quick Controls directories

Qt Quick Controls 2 was named that way because it was a follow-up to
Qt Quick Controls 1.x. Now that Qt Quick Controls 1 is no longer
supported, we don't need to have "2" in the name. Work on this was
already started for the documentation in
1abdfe5d5a052f2298b7bf657513dfa7e0c66a56.

By doing this renaming a few weeks before feature freeze, it won't
affect the release but still results in as little time possible spent
manually fixing conflicts in cherry-picks from non-LTS releases as a
result of the renaming.

This patch does the following:

- Renames directories.
- Adapts CMakeLists.txt and other files to account for the new paths.

A follow-up patch will handle documentation.

It does not touch library names or other user-facing stuff, as that
will have to be done in Qt 7.

Task-number: QTBUG-95413
Change-Id: I170d8db19033ee71e495ff0c5c1a517a41ed7634
Reviewed-by: Mitch Curtis <[email protected]>

1 files changed, 65 insertions, 0 deletions

diff --git a/src/quickcontrols/imagine/GroupBox.qml b/src/quickcontrols/imagine/GroupBox.qml
new file mode 100644
index 0000000000..e833a92da1
--- /dev/null
+++ b/src/quickcontrols/imagine/GroupBox.qml
@@ -0,0 +1,65 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
+
+import QtQuick
+import QtQuick.Templates as T
+import QtQuick.Controls.Imagine
+import QtQuick.Controls.Imagine.impl
+
+T.GroupBox {
+    id: control
+
+    implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
+                            contentWidth + leftPadding + rightPadding,
+                            implicitLabelWidth + leftPadding + rightPadding)
+    implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
+                             contentHeight + topPadding + bottomPadding)
+
+    topPadding: ((background as NinePatchImage)?.topPadding ?? 0) + (implicitLabelWidth > 0 ? implicitLabelHeight + spacing : 0)
+    leftPadding: ((background as NinePatchImage)?.leftPadding ?? 0)
+    rightPadding: ((background as NinePatchImage)?.rightPadding ?? 0)
+    bottomPadding: ((background as NinePatchImage)?.bottomPadding ?? 0)
+
+    label: Label {
+        width: control.width
+
+        topPadding: background.topPadding
+        leftPadding: background.leftPadding
+        rightPadding: background.rightPadding
+        bottomPadding: background.bottomPadding
+
+        text: control.title
+        elide: Text.ElideRight
+        verticalAlignment: Text.AlignVCenter
+
+        color: control.palette.windowText
+
+        background: NinePatchImage {
+            width: parent.width
+            height: parent.height
+
+            source: Imagine.url + "groupbox-title"
+            NinePatchImageSelector on source {
+                states: [
+                    {"disabled": !control.enabled},
+                    {"mirrored": control.mirrored}
+                ]
+            }
+        }
+    }
+
+    background: NinePatchImage {
+        x: -leftInset
+        y: control.topPadding - control.bottomPadding - topInset
+        width: control.width + leftInset + rightInset
+        height: control.height + topInset + bottomInset - control.topPadding + control.bottomPadding
+
+        source: Imagine.url + "groupbox-background"
+        NinePatchImageSelector on source {
+            states: [
+                {"disabled": !control.enabled},
+                {"mirrored": control.mirrored}
+            ]
+        }
+    }
+}