i is an integer
x is a variable
cls is a class name
m is a method name
type ::= `int` | `bool` | cls
exp ::= i | x | `this` | `true` | `false` |
        `(` `.` exp x `)` |         // access a field of an object
        `(` `new` cls exp* `)` |    // create a new object
        `(` `call` exp m exp* `)` | // call a method
        `(` op exp exp `)`          // binary operation
op ::= `+` | `*` | `<` | `&&` | `||`
lhs ::= x |
        `(` `.` `this` x `)` |
        `(` `.` lhs x `)`
stmt ::= `(` `vardec` type x exp `)` | // variable declaration
         `(` `=` lhs exp `)` |         // assignment
         `(` `while` exp stmt `)` |    // while loops
         `(` `progn` stmt* `)` |       // sequencing statements
         `(` `print` exp `)` |         // printing something
         `(` `if` exp stmt stmt `)` |  // conditionals
         `(` `return` exp `)`          // return from methods
param ::= `(` type x `)`
consdef ::= `(` `init` `(` param* `)` [`(` `super` exp* `)`] stmt `)`
classdef ::= `(` `class` cls [cls] `(` param* `)` consdef methoddef* `)`
methoddef ::= `(` `method` type m `(` param* `)` stmt `)`
program ::= classdef* stmt